NefryBTをIBM Watson IoT Platform (QuickStart) にデータ送信＆可視化するメモ

#include <Nefry.h>
#include <WiFiClient.h>
#include <PubSubClient.h>

//-------- Customise these values -----------
// 接続先のIBM Watson IoT Platform
#define ORG "quickstart" // your organization or "quickstart"
// デバイスタイプはNefry BTで
#define DEVICE_TYPE "nefrybt" // use this default for quickstart or customize to your registered device type
// デバイスIDは以下で
#define DEVICE_ID "NefryBT_123456789" // use this default for quickstart or customize to your registered device id
// quickstartでは使わないが宣言はしておく
#define TOKEN "<yourDeviceToken>" // your device token or not used with "quickstart"
//-------- Customise the above values --------

// 実際の接続するための設定群
char server[] = ORG ".messaging.internetofthings.ibmcloud.com";
char topic[] = "iot-2/evt/status/fmt/json";
char authMethod[] = "use-token-auth";
char token[] = TOKEN;
char clientId[] = "d:" ORG ":" DEVICE_TYPE ":" DEVICE_ID;

// WiFiClient準備
WiFiClient wifiClient;

// 入力の状態記録
int sensorValueState = LOW;

// ポート番号
const int port = 1883;

// 今回センサーがつながったピン番号 D2
int PIN = D2;

// MQTT接続のための準備
// QuickStartのため server , port だけ。あとはwifiClient紐付け。
PubSubClient client(server, port, wifiClient);

void setup() {
  pinMode(PIN,INPUT);
  Serial.begin(115200);
}

void loop() {

  String payload;

  // MQTT再接続処理
  if (!!!client.connected()) {
    Serial.print("Reconnecting client to "); Serial.println(server);
    while (!!!client.connect(clientId, authMethod, token)) {
      Serial.print(".");
      delay(500);
    }
    Serial.println();
  }

  // センサー反応判定
  int sensorValueCurrent = digitalRead(PIN);
  if ( sensorValueCurrent != sensorValueState ) {
    if( sensorValueCurrent == HIGH ){
      Serial.println("sensor ON");
      // IBM Watson IoT Platformに合わせてデータ構造をつくる flag = 1
      payload = "{ \"d\" : {\"flag\":1} }";
    } else {
      Serial.println("sensor OFF");
      // IBM Watson IoT Platformに合わせてデータ構造をつくる flag = 0
      payload = "{ \"d\" : {\"flag\":0} }";
    }
    // データ送信
    Serial.print("Sending payload: ");
    Serial.println(payload);
    if (client.publish(topic, (char*) payload.c_str())) {
      Serial.println("Publish ok");
    } else {
      Serial.println("Publish failed");
    }
  }
  // 入力の状態を次のループまで記憶
  sensorValueState = sensorValueCurrent;

  delay(3000);
}